1 /*
2 * CDDL HEADER START
3 *
4 * The contents of this file are subject to the terms of the
5 * Common Development and Distribution License (the "License").
6 * You may not use this file except in compliance with the License.
7 *
8 * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
9 * or http://www.opensolaris.org/os/licensing.
10 * See the License for the specific language governing permissions
11 * and limitations under the License.
12 *
13 * When distributing Covered Code, include this CDDL HEADER in each
14 * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
15 * If applicable, add the following below this CDDL HEADER, with the
16 * fields enclosed by brackets "[]" replaced with your own identifying
17 * information: Portions Copyright [yyyy] [name of copyright owner]
18 *
19 * CDDL HEADER END
20 */
21 /*
22 * Copyright (c) 2004, 2010, Oracle and/or its affiliates. All rights reserved.
23 * Copyright 2016 Joyent, Inc.
24 */
25
26 #include <sys/asm_linkage.h>
27 #include <sys/asm_misc.h>
28 #include <sys/regset.h>
29 #include <sys/privregs.h>
30 #include <sys/psw.h>
31
32 #if defined(__lint)
33
34 #include <sys/types.h>
35 #include <sys/thread.h>
36 #include <sys/systm.h>
37
38 #else /* __lint */
39
40 #include <sys/machbrand.h>
41 #include <sys/segments.h>
42 #include <sys/pcb.h>
43 #include <sys/trap.h>
44 #include <sys/ftrace.h>
45 #include <sys/traptrace.h>
46 #include <sys/clock.h>
47 #include <sys/model.h>
48 #include <sys/panic.h>
49
50 #if defined(__xpv)
51 #include <sys/hypervisor.h>
52 #endif
53
54 #include "assym.h"
55
56 #endif /* __lint */
57
58 /*
59 * We implement five flavours of system call entry points
60 *
61 * - syscall/sysretq (amd64 generic)
62 * - syscall/sysretl (i386 plus SYSC bit)
63 * - sysenter/sysexit (i386 plus SEP bit)
64 * - int/iret (i386 generic)
65 * - lcall/iret (i386 generic)
66 *
67 * The current libc included in Solaris uses int/iret as the base unoptimized
68 * kernel entry method. Older libc implementations and legacy binaries may use
69 * the lcall call gate, so it must continue to be supported.
70 *
71 * System calls that use an lcall call gate are processed in trap() via a
72 * segment-not-present trap, i.e. lcalls are extremely slow(!).
73 *
74 * The basic pattern used in the 32-bit SYSC handler at this point in time is
75 * to have the bare minimum of assembler, and get to the C handlers as
76 * quickly as possible.
77 *
78 * The 64-bit handler is much closer to the sparcv9 handler; that's
79 * because of passing arguments in registers. The 32-bit world still
80 * passes arguments on the stack -- that makes that handler substantially
81 * more complex.
82 *
83 * The two handlers share a few code fragments which are broken
84 * out into preprocessor macros below.
85 *
86 * XX64 come back and speed all this up later. The 32-bit stuff looks
87 * especially easy to speed up the argument copying part ..
88 *
89 *
90 * Notes about segment register usage (c.f. the 32-bit kernel)
91 *
92 * In the 32-bit kernel, segment registers are dutifully saved and
93 * restored on all mode transitions because the kernel uses them directly.
94 * When the processor is running in 64-bit mode, segment registers are
95 * largely ignored.
96 *
97 * %cs and %ss
98 * controlled by the hardware mechanisms that make mode transitions
99 *
100 * The remaining segment registers have to either be pointing at a valid
101 * descriptor i.e. with the 'present' bit set, or they can NULL descriptors
102 *
103 * %ds and %es
104 * always ignored
105 *
106 * %fs and %gs
107 * fsbase and gsbase are used to control the place they really point at.
108 * The kernel only depends on %gs, and controls its own gsbase via swapgs
109 *
110 * Note that loading segment registers is still costly because the GDT
111 * lookup still happens (this is because the hardware can't know that we're
112 * not setting up these segment registers for a 32-bit program). Thus we
113 * avoid doing this in the syscall path, and defer them to lwp context switch
114 * handlers, so the register values remain virtualized to the lwp.
115 */
116
117 #if defined(SYSCALLTRACE)
118 #define ORL_SYSCALLTRACE(r32) \
119 orl syscalltrace(%rip), r32
120 #else
121 #define ORL_SYSCALLTRACE(r32)
122 #endif
123
124 /*
125 * In the 32-bit kernel, we do absolutely nothing before getting into the
126 * brand callback checks. In 64-bit land, we do swapgs and then come here.
127 * We assume that the %rsp- and %r15-stashing fields in the CPU structure
128 * are still unused.
129 *
130 * Check if a brand_mach_ops callback is defined for the specified callback_id
131 * type. If so invoke it with the kernel's %gs value loaded and the following
132 * data on the stack:
133 *
134 * stack: --------------------------------------
135 * 32 | callback pointer |
136 * | 24 | user (or interrupt) stack pointer |
137 * | 16 | lwp pointer |
138 * v 8 | userland return address |
139 * 0 | callback wrapper return addr |
140 * --------------------------------------
141 *
142 * Since we're pushing the userland return address onto the kernel stack
143 * we need to get that address without accessing the user's stack (since we
144 * can't trust that data). There are different ways to get the userland
145 * return address depending on how the syscall trap was made:
146 *
147 * a) For sys_syscall and sys_syscall32 the return address is in %rcx.
148 * b) For sys_sysenter the return address is in %rdx.
149 * c) For sys_int80 and sys_syscall_int (int91), upon entry into the macro,
150 * the stack pointer points at the state saved when we took the interrupt:
151 * ------------------------
152 * | | user's %ss |
153 * | | user's %esp |
154 * | | EFLAGS register |
155 * v | user's %cs |
156 * | user's %eip |
157 * ------------------------
158 *
159 * The 2nd parameter to the BRAND_CALLBACK macro is either the
160 * BRAND_URET_FROM_REG or BRAND_URET_FROM_INTR_STACK macro. These macros are
161 * used to generate the proper code to get the userland return address for
162 * each syscall entry point.
163 *
164 * The interface to the brand callbacks on the 64-bit kernel assumes %r15
165 * is available as a scratch register within the callback. If the callback
166 * returns within the kernel then this macro will restore %r15. If the
167 * callback is going to return directly to userland then it should restore
168 * %r15 before returning to userland.
169 */
170 #define BRAND_URET_FROM_REG(rip_reg) \
171 pushq rip_reg /* push the return address */
172
173 /*
174 * The interrupt stack pointer we saved on entry to the BRAND_CALLBACK macro
175 * is currently pointing at the user return address (%eip).
176 */
177 #define BRAND_URET_FROM_INTR_STACK() \
178 movq %gs:CPU_RTMP_RSP, %r15 /* grab the intr. stack pointer */ ;\
179 pushq (%r15) /* push the return address */
180
181 #define BRAND_CALLBACK(callback_id, push_userland_ret) \
182 movq %rsp, %gs:CPU_RTMP_RSP /* save the stack pointer */ ;\
183 movq %r15, %gs:CPU_RTMP_R15 /* save %r15 */ ;\
184 movq %gs:CPU_THREAD, %r15 /* load the thread pointer */ ;\
185 movq T_STACK(%r15), %rsp /* switch to the kernel stack */ ;\
186 subq $16, %rsp /* save space for 2 pointers */ ;\
187 pushq %r14 /* save %r14 */ ;\
188 movq %gs:CPU_RTMP_RSP, %r14 ;\
189 movq %r14, 8(%rsp) /* stash the user stack pointer */ ;\
190 popq %r14 /* restore %r14 */ ;\
191 movq T_LWP(%r15), %r15 /* load the lwp pointer */ ;\
192 pushq %r15 /* push the lwp pointer */ ;\
193 movq LWP_PROCP(%r15), %r15 /* load the proc pointer */ ;\
194 movq P_BRAND(%r15), %r15 /* load the brand pointer */ ;\
195 movq B_MACHOPS(%r15), %r15 /* load the machops pointer */ ;\
196 movq _CONST(_MUL(callback_id, CPTRSIZE))(%r15), %r15 ;\
197 cmpq $0, %r15 ;\
198 je 1f ;\
199 movq %r15, 16(%rsp) /* save the callback pointer */ ;\
200 push_userland_ret /* push the return address */ ;\
201 call *24(%rsp) /* call callback */ ;\
202 1: movq %gs:CPU_RTMP_R15, %r15 /* restore %r15 */ ;\
203 movq %gs:CPU_RTMP_RSP, %rsp /* restore the stack pointer */
204
205 #define MSTATE_TRANSITION(from, to) \
206 movl $from, %edi; \
207 movl $to, %esi; \
208 call syscall_mstate
209
210 /*
211 * Check to see if a simple (direct) return is possible i.e.
212 *
213 * if (t->t_post_sys_ast | syscalltrace |
214 * lwp->lwp_pcb.pcb_rupdate == 1)
215 * do full version ;
216 *
217 * Preconditions:
218 * - t is curthread
219 * Postconditions:
220 * - condition code NE is set if post-sys is too complex
221 * - rtmp is zeroed if it isn't (we rely on this!)
222 * - ltmp is smashed
223 */
224 #define CHECK_POSTSYS_NE(t, ltmp, rtmp) \
225 movq T_LWP(t), ltmp; \
226 movzbl PCB_RUPDATE(ltmp), rtmp; \
227 ORL_SYSCALLTRACE(rtmp); \
228 orl T_POST_SYS_AST(t), rtmp; \
229 cmpl $0, rtmp
230
231 /*
232 * Fix up the lwp, thread, and eflags for a successful return
233 *
234 * Preconditions:
235 * - zwreg contains zero
236 */
237 #define SIMPLE_SYSCALL_POSTSYS(t, lwp, zwreg) \
238 movb $LWP_USER, LWP_STATE(lwp); \
239 movw zwreg, T_SYSNUM(t); \
240 andb $_CONST(0xffff - PS_C), REGOFF_RFL(%rsp)
241
242 /*
243 * ASSERT(lwptoregs(lwp) == rp);
244 *
245 * This may seem obvious, but very odd things happen if this
246 * assertion is false
247 *
248 * Preconditions:
249 * (%rsp is ready for normal call sequence)
250 * Postconditions (if assertion is true):
251 * %r11 is smashed
252 *
253 * ASSERT(rp->r_cs == descnum)
254 *
255 * The code selector is written into the regs structure when the
256 * lwp stack is created. We use this ASSERT to validate that
257 * the regs structure really matches how we came in.
258 *
259 * Preconditions:
260 * (%rsp is ready for normal call sequence)
261 * Postconditions (if assertion is true):
262 * -none-
263 *
264 * ASSERT(lwp->lwp_pcb.pcb_rupdate == 0);
265 *
266 * If this is false, it meant that we returned to userland without
267 * updating the segment registers as we were supposed to.
268 *
269 * Note that we must ensure no interrupts or other traps intervene
270 * between entering privileged mode and performing the assertion,
271 * otherwise we may perform a context switch on the thread, which
272 * will end up setting pcb_rupdate to 1 again.
273 */
274 #if defined(DEBUG)
275
276 #if !defined(__lint)
277
278 __lwptoregs_msg:
279 .string "syscall_asm_amd64.s:%d lwptoregs(%p) [%p] != rp [%p]"
280
281 __codesel_msg:
282 .string "syscall_asm_amd64.s:%d rp->r_cs [%ld] != %ld"
283
284 __no_rupdate_msg:
285 .string "syscall_asm_amd64.s:%d lwp %p, pcb_rupdate != 0"
286
287 #endif /* !__lint */
288
289 #define ASSERT_LWPTOREGS(lwp, rp) \
290 movq LWP_REGS(lwp), %r11; \
291 cmpq rp, %r11; \
292 je 7f; \
293 leaq __lwptoregs_msg(%rip), %rdi; \
294 movl $__LINE__, %esi; \
295 movq lwp, %rdx; \
296 movq %r11, %rcx; \
297 movq rp, %r8; \
298 xorl %eax, %eax; \
299 call panic; \
300 7:
301
302 #define ASSERT_NO_RUPDATE_PENDING(lwp) \
303 testb $0x1, PCB_RUPDATE(lwp); \
304 je 8f; \
305 movq lwp, %rdx; \
306 leaq __no_rupdate_msg(%rip), %rdi; \
307 movl $__LINE__, %esi; \
308 xorl %eax, %eax; \
309 call panic; \
310 8:
311
312 #else
313 #define ASSERT_LWPTOREGS(lwp, rp)
314 #define ASSERT_NO_RUPDATE_PENDING(lwp)
315 #endif
316
317 /*
318 * Do the traptrace thing and restore any registers we used
319 * in situ. Assumes that %rsp is pointing at the base of
320 * the struct regs, obviously ..
321 */
322 #ifdef TRAPTRACE
323 #define SYSCALL_TRAPTRACE(ttype) \
324 TRACE_PTR(%rdi, %rbx, %ebx, %rcx, ttype); \
325 TRACE_REGS(%rdi, %rsp, %rbx, %rcx); \
326 TRACE_STAMP(%rdi); /* rdtsc clobbers %eax, %edx */ \
327 movq REGOFF_RAX(%rsp), %rax; \
328 movq REGOFF_RBX(%rsp), %rbx; \
329 movq REGOFF_RCX(%rsp), %rcx; \
330 movq REGOFF_RDX(%rsp), %rdx; \
331 movl %eax, TTR_SYSNUM(%rdi); \
332 movq REGOFF_RDI(%rsp), %rdi
333
334 #define SYSCALL_TRAPTRACE32(ttype) \
335 SYSCALL_TRAPTRACE(ttype); \
336 /* paranoia: clean the top 32-bits of the registers */ \
337 orl %eax, %eax; \
338 orl %ebx, %ebx; \
339 orl %ecx, %ecx; \
340 orl %edx, %edx; \
341 orl %edi, %edi
342 #else /* TRAPTRACE */
343 #define SYSCALL_TRAPTRACE(ttype)
344 #define SYSCALL_TRAPTRACE32(ttype)
345 #endif /* TRAPTRACE */
346
347 /*
348 * The 64-bit libc syscall wrapper does this:
349 *
350 * fn(<args>)
351 * {
352 * movq %rcx, %r10 -- because syscall smashes %rcx
353 * movl $CODE, %eax
354 * syscall
355 * <error processing>
356 * }
357 *
358 * Thus when we come into the kernel:
359 *
360 * %rdi, %rsi, %rdx, %r10, %r8, %r9 contain first six args
361 * %rax is the syscall number
362 * %r12-%r15 contain caller state
363 *
364 * The syscall instruction arranges that:
365 *
366 * %rcx contains the return %rip
367 * %r11d contains bottom 32-bits of %rflags
368 * %rflags is masked (as determined by the SFMASK msr)
369 * %cs is set to UCS_SEL (as determined by the STAR msr)
370 * %ss is set to UDS_SEL (as determined by the STAR msr)
371 * %rip is set to sys_syscall (as determined by the LSTAR msr)
372 *
373 * Or in other words, we have no registers available at all.
374 * Only swapgs can save us!
375 *
376 * Under the hypervisor, the swapgs has happened already. However, the
377 * state of the world is very different from that we're familiar with.
378 *
379 * In particular, we have a stack structure like that for interrupt
380 * gates, except that the %cs and %ss registers are modified for reasons
381 * that are not entirely clear. Critically, the %rcx/%r11 values do
382 * *not* reflect the usage of those registers under a 'real' syscall[1];
383 * the stack, therefore, looks like this:
384 *
385 * 0x0(rsp) potentially junk %rcx
386 * 0x8(rsp) potentially junk %r11
387 * 0x10(rsp) user %rip
388 * 0x18(rsp) modified %cs
389 * 0x20(rsp) user %rflags
390 * 0x28(rsp) user %rsp
391 * 0x30(rsp) modified %ss
392 *
393 *
394 * and before continuing on, we must load the %rip into %rcx and the
395 * %rflags into %r11.
396 *
397 * [1] They used to, and we relied on it, but this was broken in 3.1.1.
398 * Sigh.
399 */
400 #if defined(__xpv)
401 #define XPV_SYSCALL_PROD \
402 movq 0x10(%rsp), %rcx; \
403 movq 0x20(%rsp), %r11; \
404 movq 0x28(%rsp), %rsp
405 #else
406 #define XPV_SYSCALL_PROD /* nothing */
407 #endif
408
409 #if defined(__lint)
410
411 /*ARGSUSED*/
412 void
413 sys_syscall()
414 {}
415
416 void
417 _allsyscalls()
418 {}
419
420 size_t _allsyscalls_size;
421
422 #else /* __lint */
423
424 ENTRY_NP2(brand_sys_syscall,_allsyscalls)
425 SWAPGS /* kernel gsbase */
426 XPV_SYSCALL_PROD
427 BRAND_CALLBACK(BRAND_CB_SYSCALL, BRAND_URET_FROM_REG(%rcx))
428 jmp noprod_sys_syscall
429
430 ALTENTRY(sys_syscall)
431 SWAPGS /* kernel gsbase */
432 XPV_SYSCALL_PROD
433
434 noprod_sys_syscall:
435 movq %r15, %gs:CPU_RTMP_R15
436 movq %rsp, %gs:CPU_RTMP_RSP
437
438 movq %gs:CPU_THREAD, %r15
439 movq T_STACK(%r15), %rsp /* switch from user to kernel stack */
440
441 ASSERT_UPCALL_MASK_IS_SET
442
443 movl $UCS_SEL, REGOFF_CS(%rsp)
444 movq %rcx, REGOFF_RIP(%rsp) /* syscall: %rip -> %rcx */
445 movq %r11, REGOFF_RFL(%rsp) /* syscall: %rfl -> %r11d */
446 movl $UDS_SEL, REGOFF_SS(%rsp)
447
448 movl %eax, %eax /* wrapper: sysc# -> %eax */
449 movq %rdi, REGOFF_RDI(%rsp)
450 movq %rsi, REGOFF_RSI(%rsp)
451 movq %rdx, REGOFF_RDX(%rsp)
452 movq %r10, REGOFF_RCX(%rsp) /* wrapper: %rcx -> %r10 */
453 movq %r10, %rcx /* arg[3] for direct calls */
454
455 movq %r8, REGOFF_R8(%rsp)
456 movq %r9, REGOFF_R9(%rsp)
457 movq %rax, REGOFF_RAX(%rsp)
458 movq %rbx, REGOFF_RBX(%rsp)
459
460 movq %rbp, REGOFF_RBP(%rsp)
461 movq %r10, REGOFF_R10(%rsp)
462 movq %gs:CPU_RTMP_RSP, %r11
463 movq %r11, REGOFF_RSP(%rsp)
464 movq %r12, REGOFF_R12(%rsp)
465
466 movq %r13, REGOFF_R13(%rsp)
467 movq %r14, REGOFF_R14(%rsp)
468 movq %gs:CPU_RTMP_R15, %r10
469 movq %r10, REGOFF_R15(%rsp)
470 movq $0, REGOFF_SAVFP(%rsp)
471 movq $0, REGOFF_SAVPC(%rsp)
472
473 /*
474 * Copy these registers here in case we end up stopped with
475 * someone (like, say, /proc) messing with our register state.
476 * We don't -restore- them unless we have to in update_sregs.
477 *
478 * Since userland -can't- change fsbase or gsbase directly,
479 * and capturing them involves two serializing instructions,
480 * we don't bother to capture them here.
481 */
482 xorl %ebx, %ebx
483 movw %ds, %bx
484 movq %rbx, REGOFF_DS(%rsp)
485 movw %es, %bx
486 movq %rbx, REGOFF_ES(%rsp)
487 movw %fs, %bx
488 movq %rbx, REGOFF_FS(%rsp)
489 movw %gs, %bx
490 movq %rbx, REGOFF_GS(%rsp)
491
492 /*
493 * Machine state saved in the regs structure on the stack
494 * First six args in %rdi, %rsi, %rdx, %rcx, %r8, %r9
495 * %eax is the syscall number
496 * %rsp is the thread's stack, %r15 is curthread
497 * REG_RSP(%rsp) is the user's stack
498 */
499
500 SYSCALL_TRAPTRACE($TT_SYSC64)
501
502 movq %rsp, %rbp
503
504 movq T_LWP(%r15), %r14
505 ASSERT_NO_RUPDATE_PENDING(%r14)
506
507 ENABLE_INTR_FLAGS
508
509 MSTATE_TRANSITION(LMS_USER, LMS_SYSTEM)
510 movl REGOFF_RAX(%rsp), %eax /* (%rax damaged by mstate call) */
511
512 ASSERT_LWPTOREGS(%r14, %rsp)
513
514 movb $LWP_SYS, LWP_STATE(%r14)
515 incq LWP_RU_SYSC(%r14)
516 movb $NORMALRETURN, LWP_EOSYS(%r14)
517
518 incq %gs:CPU_STATS_SYS_SYSCALL
519
520 /*
521 * If our LWP has an alternate system call handler, run that instead of
522 * the regular system call path.
523 */
524 movq LWP_BRAND_SYSCALL(%r14), %rdi
525 testq %rdi, %rdi
526 jz _syscall_no_brand
527
528 pushq %rax
529 subq $8, %rsp /* align stack for call to C */
530 call *%rdi
531 addq $8, %rsp
532
533 /*
534 * If the alternate handler returns 0, we skip straight to the return to
535 * usermode. Otherwise, we resume regular system call processing.
536 */
537 testl %eax, %eax
538 popq %rax
539 jz _syscall_after_brand
540
541 _syscall_no_brand:
542 movw %ax, T_SYSNUM(%r15)
543 movzbl T_PRE_SYS(%r15), %ebx
544 ORL_SYSCALLTRACE(%ebx)
545 testl %ebx, %ebx
546 jne _syscall_pre
547
548 _syscall_invoke:
549 movq REGOFF_RDI(%rbp), %rdi
550 movq REGOFF_RSI(%rbp), %rsi
551 movq REGOFF_RDX(%rbp), %rdx
552 movq REGOFF_RCX(%rbp), %rcx
553 movq REGOFF_R8(%rbp), %r8
554 movq REGOFF_R9(%rbp), %r9
555
556 cmpl $NSYSCALL, %eax
557 jae _syscall_ill
558 shll $SYSENT_SIZE_SHIFT, %eax
559 leaq sysent(%rax), %rbx
560
561 call *SY_CALLC(%rbx)
562
563 movq %rax, %r12
564 movq %rdx, %r13
565
566 /*
567 * If the handler returns two ints, then we need to split the
568 * 64-bit return value into two 32-bit values.
569 */
570 testw $SE_32RVAL2, SY_FLAGS(%rbx)
571 je 5f
572 movq %r12, %r13
573 shrq $32, %r13 /* upper 32-bits into %edx */
574 movl %r12d, %r12d /* lower 32-bits into %eax */
575 5:
576
577 _syscall_after_brand:
578 /*
579 * Optimistically assume that there's no post-syscall
580 * work to do. (This is to avoid having to call syscall_mstate()
581 * with interrupts disabled)
582 */
583 MSTATE_TRANSITION(LMS_SYSTEM, LMS_USER)
584
585 /*
586 * We must protect ourselves from being descheduled here;
587 * If we were, and we ended up on another cpu, or another
588 * lwp got in ahead of us, it could change the segment
589 * registers without us noticing before we return to userland.
590 */
591 CLI(%r14)
592 CHECK_POSTSYS_NE(%r15, %r14, %ebx)
593 jne _syscall_post
594
595 /*
596 * We need to protect ourselves against non-canonical return values
597 * because Intel doesn't check for them on sysret (AMD does). Canonical
598 * addresses on current amd64 processors only use 48-bits for VAs; an
599 * address is canonical if all upper bits (47-63) are identical. If we
600 * find a non-canonical %rip, we opt to go through the full
601 * _syscall_post path which takes us into an iretq which is not
602 * susceptible to the same problems sysret is.
603 *
604 * We're checking for a canonical address by first doing an arithmetic
605 * shift. This will fill in the remaining bits with the value of bit 63.
606 * If the address were canonical, the register would now have either all
607 * zeroes or all ones in it. Therefore we add one (inducing overflow)
608 * and compare against 1. A canonical address will either be zero or one
609 * at this point, hence the use of ja.
610 *
611 * At this point, r12 and r13 have the return value so we can't use
612 * those registers.
613 */
614 movq REGOFF_RIP(%rsp), %rcx
615 sarq $47, %rcx
616 incq %rcx
617 cmpq $1, %rcx
618 ja _syscall_post
619
620
621 SIMPLE_SYSCALL_POSTSYS(%r15, %r14, %bx)
622
623 movq %r12, REGOFF_RAX(%rsp)
624 movq %r13, REGOFF_RDX(%rsp)
625
626 /*
627 * To get back to userland, we need the return %rip in %rcx and
628 * the return %rfl in %r11d. The sysretq instruction also arranges
629 * to fix up %cs and %ss; everything else is our responsibility.
630 */
631 movq REGOFF_RDI(%rsp), %rdi
632 movq REGOFF_RSI(%rsp), %rsi
633 movq REGOFF_RDX(%rsp), %rdx
634 /* %rcx used to restore %rip value */
635
636 movq REGOFF_R8(%rsp), %r8
637 movq REGOFF_R9(%rsp), %r9
638 movq REGOFF_RAX(%rsp), %rax
639 movq REGOFF_RBX(%rsp), %rbx
640
641 movq REGOFF_RBP(%rsp), %rbp
642 movq REGOFF_R10(%rsp), %r10
643 /* %r11 used to restore %rfl value */
644 movq REGOFF_R12(%rsp), %r12
645
646 movq REGOFF_R13(%rsp), %r13
647 movq REGOFF_R14(%rsp), %r14
648 movq REGOFF_R15(%rsp), %r15
649
650 movq REGOFF_RIP(%rsp), %rcx
651 movl REGOFF_RFL(%rsp), %r11d
652
653 #if defined(__xpv)
654 addq $REGOFF_RIP, %rsp
655 #else
656 movq REGOFF_RSP(%rsp), %rsp
657 #endif
658
659 /*
660 * There can be no instructions between the ALTENTRY below and
661 * SYSRET or we could end up breaking brand support. See label usage
662 * in sn1_brand_syscall_callback for an example.
663 */
664 ASSERT_UPCALL_MASK_IS_SET
665 #if defined(__xpv)
666 SYSRETQ
667 ALTENTRY(nopop_sys_syscall_swapgs_sysretq)
668
669 /*
670 * We can only get here after executing a brand syscall
671 * interposition callback handler and simply need to
672 * "sysretq" back to userland. On the hypervisor this
673 * involves the iret hypercall which requires us to construct
674 * just enough of the stack needed for the hypercall.
675 * (rip, cs, rflags, rsp, ss).
676 */
677 movq %rsp, %gs:CPU_RTMP_RSP /* save user's rsp */
678 movq %gs:CPU_THREAD, %r11
679 movq T_STACK(%r11), %rsp
680
681 movq %rcx, REGOFF_RIP(%rsp)
682 movl $UCS_SEL, REGOFF_CS(%rsp)
683 movq %gs:CPU_RTMP_RSP, %r11
684 movq %r11, REGOFF_RSP(%rsp)
685 pushfq
686 popq %r11 /* hypercall enables ints */
687 movq %r11, REGOFF_RFL(%rsp)
688 movl $UDS_SEL, REGOFF_SS(%rsp)
689 addq $REGOFF_RIP, %rsp
690 /*
691 * XXPV: see comment in SYSRETQ definition for future optimization
692 * we could take.
693 */
694 ASSERT_UPCALL_MASK_IS_SET
695 SYSRETQ
696 #else
697 ALTENTRY(nopop_sys_syscall_swapgs_sysretq)
698 SWAPGS /* user gsbase */
699 SYSRETQ
700 #endif
701 /*NOTREACHED*/
702 SET_SIZE(nopop_sys_syscall_swapgs_sysretq)
703
704 _syscall_pre:
705 call pre_syscall
706 movl %eax, %r12d
707 testl %eax, %eax
708 jne _syscall_post_call
709 /*
710 * Didn't abort, so reload the syscall args and invoke the handler.
711 */
712 movzwl T_SYSNUM(%r15), %eax
713 jmp _syscall_invoke
714
715 _syscall_ill:
716 call nosys
717 movq %rax, %r12
718 movq %rdx, %r13
719 jmp _syscall_post_call
720
721 _syscall_post:
722 STI
723 /*
724 * Sigh, our optimism wasn't justified, put it back to LMS_SYSTEM
725 * so that we can account for the extra work it takes us to finish.
726 */
727 MSTATE_TRANSITION(LMS_USER, LMS_SYSTEM)
728 _syscall_post_call:
729 movq %r12, %rdi
730 movq %r13, %rsi
731 call post_syscall
732 MSTATE_TRANSITION(LMS_SYSTEM, LMS_USER)
733 jmp _sys_rtt
734 SET_SIZE(sys_syscall)
735 SET_SIZE(brand_sys_syscall)
736
737 #endif /* __lint */
738
739 #if defined(__lint)
740
741 /*ARGSUSED*/
742 void
743 sys_syscall32()
744 {}
745
746 #else /* __lint */
747
748 ENTRY_NP(brand_sys_syscall32)
749 SWAPGS /* kernel gsbase */
750 XPV_TRAP_POP
751 BRAND_CALLBACK(BRAND_CB_SYSCALL32, BRAND_URET_FROM_REG(%rcx))
752 jmp nopop_sys_syscall32
753
754 ALTENTRY(sys_syscall32)
755 SWAPGS /* kernel gsbase */
756 XPV_TRAP_POP
757
758 nopop_sys_syscall32:
759 movl %esp, %r10d
760 movq %gs:CPU_THREAD, %r15
761 movq T_STACK(%r15), %rsp
762 movl %eax, %eax
763
764 movl $U32CS_SEL, REGOFF_CS(%rsp)
765 movl %ecx, REGOFF_RIP(%rsp) /* syscall: %rip -> %rcx */
766 movq %r11, REGOFF_RFL(%rsp) /* syscall: %rfl -> %r11d */
767 movq %r10, REGOFF_RSP(%rsp)
768 movl $UDS_SEL, REGOFF_SS(%rsp)
769
770 _syscall32_save:
771 movl %edi, REGOFF_RDI(%rsp)
772 movl %esi, REGOFF_RSI(%rsp)
773 movl %ebp, REGOFF_RBP(%rsp)
774 movl %ebx, REGOFF_RBX(%rsp)
775 movl %edx, REGOFF_RDX(%rsp)
776 movl %ecx, REGOFF_RCX(%rsp)
777 movl %eax, REGOFF_RAX(%rsp) /* wrapper: sysc# -> %eax */
778 movq $0, REGOFF_SAVFP(%rsp)
779 movq $0, REGOFF_SAVPC(%rsp)
780
781 /*
782 * Copy these registers here in case we end up stopped with
783 * someone (like, say, /proc) messing with our register state.
784 * We don't -restore- them unless we have to in update_sregs.
785 *
786 * Since userland -can't- change fsbase or gsbase directly,
787 * we don't bother to capture them here.
788 */
789 xorl %ebx, %ebx
790 movw %ds, %bx
791 movq %rbx, REGOFF_DS(%rsp)
792 movw %es, %bx
793 movq %rbx, REGOFF_ES(%rsp)
794 movw %fs, %bx
795 movq %rbx, REGOFF_FS(%rsp)
796 movw %gs, %bx
797 movq %rbx, REGOFF_GS(%rsp)
798
799 /*
800 * Application state saved in the regs structure on the stack
801 * %eax is the syscall number
802 * %rsp is the thread's stack, %r15 is curthread
803 * REG_RSP(%rsp) is the user's stack
804 */
805
806 SYSCALL_TRAPTRACE32($TT_SYSC)
807
808 movq %rsp, %rbp
809
810 movq T_LWP(%r15), %r14
811 ASSERT_NO_RUPDATE_PENDING(%r14)
812
813 ENABLE_INTR_FLAGS
814
815 MSTATE_TRANSITION(LMS_USER, LMS_SYSTEM)
816 movl REGOFF_RAX(%rsp), %eax /* (%rax damaged by mstate call) */
817
818 ASSERT_LWPTOREGS(%r14, %rsp)
819
820 incq %gs:CPU_STATS_SYS_SYSCALL
821
822 /*
823 * If our lwp has an alternate system call handler, run that instead
824 * of the regular system call path.
825 */
826 movq LWP_BRAND_SYSCALL(%r14), %rax
827 testq %rax, %rax
828 jz _syscall32_no_brand
829
830 movb $LWP_SYS, LWP_STATE(%r14)
831 call *%rax
832
833 /*
834 * If the alternate handler returns 0, we skip straight to the return
835 * to usermode. Otherwise, we resume regular system call processing.
836 */
837 testl %eax, %eax
838 jz _syscall32_after_brand
839
840 _syscall32_no_brand:
841 /*
842 * Make some space for MAXSYSARGS (currently 8) 32-bit args placed
843 * into 64-bit (long) arg slots, maintaining 16 byte alignment. Or
844 * more succinctly:
845 *
846 * SA(MAXSYSARGS * sizeof (long)) == 64
847 *
848 * Note, this space is used both to copy in the arguments from user
849 * land, but also to as part of the old UNIX style syscall_ap() method.
850 * syscall_entry expects that we do not change the values of this space
851 * that we give it. However, this means that when we end up in the more
852 * recent model of passing the arguments based on the calling
853 * conventions, we'll need to save an additional 16 bytes of stack.
854 */
855 #define SYS_DROP 64 /* drop for args */
856 subq $SYS_DROP, %rsp
857 movb $LWP_SYS, LWP_STATE(%r14)
858 movq %r15, %rdi
859 movq %rsp, %rsi
860 call syscall_entry
861
862 /*
863 * Fetch the arguments copied onto the kernel stack and put
864 * them in the right registers to invoke a C-style syscall handler.
865 * %rax contains the handler address.
866 *
867 * Ideas for making all this go faster of course include simply
868 * forcibly fetching 6 arguments from the user stack under lofault
869 * protection, reverting to copyin_args only when watchpoints
870 * are in effect.
871 *
872 * (If we do this, make sure that exec and libthread leave
873 * enough space at the top of the stack to ensure that we'll
874 * never do a fetch from an invalid page.)
875 *
876 * Lots of ideas here, but they won't really help with bringup B-)
877 * Correctness can't wait, performance can wait a little longer ..
878 */
879
880 movq %rax, %rbx
881 movl 0x0(%rsp), %edi /* arg0 */
882 movl 0x8(%rsp), %esi /* arg1 */
883 movl 0x10(%rsp), %edx /* arg2 */
884 movl 0x38(%rsp), %eax /* arg7 load */
885 movl 0x18(%rsp), %ecx /* arg3 */
886 pushq %rax /* arg7 saved to stack */
887 movl 0x28(%rsp), %r8d /* arg4 */
888 movl 0x38(%rsp), %eax /* arg6 load */
889 movl 0x30(%rsp), %r9d /* arg5 */
890 pushq %rax /* arg6 saved to stack */
891
892 call *SY_CALLC(%rbx)
893
894 movq %rbp, %rsp /* pop the args */
895
896 /*
897 * amd64 syscall handlers -always- return a 64-bit value in %rax.
898 * On the 32-bit kernel, they always return that value in %eax:%edx
899 * as required by the 32-bit ABI.
900 *
901 * Simulate the same behaviour by unconditionally splitting the
902 * return value in the same way.
903 */
904 movq %rax, %r13
905 shrq $32, %r13 /* upper 32-bits into %edx */
906 movl %eax, %r12d /* lower 32-bits into %eax */
907
908 _syscall32_after_brand:
909
910 /*
911 * Optimistically assume that there's no post-syscall
912 * work to do. (This is to avoid having to call syscall_mstate()
913 * with interrupts disabled)
914 */
915 MSTATE_TRANSITION(LMS_SYSTEM, LMS_USER)
916
917 /*
918 * We must protect ourselves from being descheduled here;
919 * If we were, and we ended up on another cpu, or another
920 * lwp got in ahead of us, it could change the segment
921 * registers without us noticing before we return to userland.
922 */
923 CLI(%r14)
924 CHECK_POSTSYS_NE(%r15, %r14, %ebx)
925 jne _full_syscall_postsys32
926 SIMPLE_SYSCALL_POSTSYS(%r15, %r14, %bx)
927
928 /*
929 * To get back to userland, we need to put the return %rip in %rcx and
930 * the return %rfl in %r11d. The sysret instruction also arranges
931 * to fix up %cs and %ss; everything else is our responsibility.
932 */
933
934 movl %r12d, %eax /* %eax: rval1 */
935 movl REGOFF_RBX(%rsp), %ebx
936 /* %ecx used for return pointer */
937 movl %r13d, %edx /* %edx: rval2 */
938 movl REGOFF_RBP(%rsp), %ebp
939 movl REGOFF_RSI(%rsp), %esi
940 movl REGOFF_RDI(%rsp), %edi
941
942 movl REGOFF_RFL(%rsp), %r11d /* %r11 -> eflags */
943 movl REGOFF_RIP(%rsp), %ecx /* %ecx -> %eip */
944 movl REGOFF_RSP(%rsp), %esp
945
946 ASSERT_UPCALL_MASK_IS_SET
947 ALTENTRY(nopop_sys_syscall32_swapgs_sysretl)
948 SWAPGS /* user gsbase */
949 SYSRETL
950 SET_SIZE(nopop_sys_syscall32_swapgs_sysretl)
951 /*NOTREACHED*/
952
953 _full_syscall_postsys32:
954 STI
955 /*
956 * Sigh, our optimism wasn't justified, put it back to LMS_SYSTEM
957 * so that we can account for the extra work it takes us to finish.
958 */
959 MSTATE_TRANSITION(LMS_USER, LMS_SYSTEM)
960 movq %r15, %rdi
961 movq %r12, %rsi /* rval1 - %eax */
962 movq %r13, %rdx /* rval2 - %edx */
963 call syscall_exit
964 MSTATE_TRANSITION(LMS_SYSTEM, LMS_USER)
965 jmp _sys_rtt
966 SET_SIZE(sys_syscall32)
967 SET_SIZE(brand_sys_syscall32)
968
969 #endif /* __lint */
970
971 /*
972 * System call handler via the sysenter instruction
973 * Used only for 32-bit system calls on the 64-bit kernel.
974 *
975 * The caller in userland has arranged that:
976 *
977 * - %eax contains the syscall number
978 * - %ecx contains the user %esp
979 * - %edx contains the return %eip
980 * - the user stack contains the args to the syscall
981 *
982 * Hardware and (privileged) initialization code have arranged that by
983 * the time the sysenter instructions completes:
984 *
985 * - %rip is pointing to sys_sysenter (below).
986 * - %cs and %ss are set to kernel text and stack (data) selectors.
987 * - %rsp is pointing at the lwp's stack
988 * - interrupts have been disabled.
989 *
990 * Note that we are unable to return both "rvals" to userland with
991 * this call, as %edx is used by the sysexit instruction.
992 *
993 * One final complication in this routine is its interaction with
994 * single-stepping in a debugger. For most of the system call mechanisms,
995 * the CPU automatically clears the single-step flag before we enter the
996 * kernel. The sysenter mechanism does not clear the flag, so a user
997 * single-stepping through a libc routine may suddenly find him/herself
998 * single-stepping through the kernel. To detect this, kmdb compares the
999 * trap %pc to the [brand_]sys_enter addresses on each single-step trap.
1000 * If it finds that we have single-stepped to a sysenter entry point, it
1001 * explicitly clears the flag and executes the sys_sysenter routine.
1002 *
1003 * One final complication in this final complication is the fact that we
1004 * have two different entry points for sysenter: brand_sys_sysenter and
1005 * sys_sysenter. If we enter at brand_sys_sysenter and start single-stepping
1006 * through the kernel with kmdb, we will eventually hit the instruction at
1007 * sys_sysenter. kmdb cannot distinguish between that valid single-step
1008 * and the undesirable one mentioned above. To avoid this situation, we
1009 * simply add a jump over the instruction at sys_sysenter to make it
1010 * impossible to single-step to it.
1011 */
1012 #if defined(__lint)
1013
1014 void
1015 sys_sysenter()
1016 {}
1017
1018 #else /* __lint */
1019
1020 ENTRY_NP(brand_sys_sysenter)
1021 SWAPGS /* kernel gsbase */
1022 ALTENTRY(_brand_sys_sysenter_post_swapgs)
1023 BRAND_CALLBACK(BRAND_CB_SYSENTER, BRAND_URET_FROM_REG(%rdx))
1024 /*
1025 * Jump over sys_sysenter to allow single-stepping as described
1026 * above.
1027 */
1028 jmp _sys_sysenter_post_swapgs
1029
1030 ALTENTRY(sys_sysenter)
1031 SWAPGS /* kernel gsbase */
1032
1033 ALTENTRY(_sys_sysenter_post_swapgs)
1034 movq %gs:CPU_THREAD, %r15
1035
1036 movl $U32CS_SEL, REGOFF_CS(%rsp)
1037 movl %ecx, REGOFF_RSP(%rsp) /* wrapper: %esp -> %ecx */
1038 movl %edx, REGOFF_RIP(%rsp) /* wrapper: %eip -> %edx */
1039 pushfq
1040 popq %r10
1041 movl $UDS_SEL, REGOFF_SS(%rsp)
1042
1043 /*
1044 * Set the interrupt flag before storing the flags to the
1045 * flags image on the stack so we can return to user with
1046 * interrupts enabled if we return via sys_rtt_syscall32
1047 */
1048 orq $PS_IE, %r10
1049 movq %r10, REGOFF_RFL(%rsp)
1050
1051 movl %edi, REGOFF_RDI(%rsp)
1052 movl %esi, REGOFF_RSI(%rsp)
1053 movl %ebp, REGOFF_RBP(%rsp)
1054 movl %ebx, REGOFF_RBX(%rsp)
1055 movl %edx, REGOFF_RDX(%rsp)
1056 movl %ecx, REGOFF_RCX(%rsp)
1057 movl %eax, REGOFF_RAX(%rsp) /* wrapper: sysc# -> %eax */
1058 movq $0, REGOFF_SAVFP(%rsp)
1059 movq $0, REGOFF_SAVPC(%rsp)
1060
1061 /*
1062 * Copy these registers here in case we end up stopped with
1063 * someone (like, say, /proc) messing with our register state.
1064 * We don't -restore- them unless we have to in update_sregs.
1065 *
1066 * Since userland -can't- change fsbase or gsbase directly,
1067 * we don't bother to capture them here.
1068 */
1069 xorl %ebx, %ebx
1070 movw %ds, %bx
1071 movq %rbx, REGOFF_DS(%rsp)
1072 movw %es, %bx
1073 movq %rbx, REGOFF_ES(%rsp)
1074 movw %fs, %bx
1075 movq %rbx, REGOFF_FS(%rsp)
1076 movw %gs, %bx
1077 movq %rbx, REGOFF_GS(%rsp)
1078
1079 /*
1080 * Application state saved in the regs structure on the stack
1081 * %eax is the syscall number
1082 * %rsp is the thread's stack, %r15 is curthread
1083 * REG_RSP(%rsp) is the user's stack
1084 */
1085
1086 SYSCALL_TRAPTRACE($TT_SYSENTER)
1087
1088 movq %rsp, %rbp
1089
1090 movq T_LWP(%r15), %r14
1091 ASSERT_NO_RUPDATE_PENDING(%r14)
1092
1093 ENABLE_INTR_FLAGS
1094
1095 /*
1096 * Catch 64-bit process trying to issue sysenter instruction
1097 * on Nocona based systems.
1098 */
1099 movq LWP_PROCP(%r14), %rax
1100 cmpq $DATAMODEL_ILP32, P_MODEL(%rax)
1101 je 7f
1102
1103 /*
1104 * For a non-32-bit process, simulate a #ud, since that's what
1105 * native hardware does. The traptrace entry (above) will
1106 * let you know what really happened.
1107 */
1108 movq $T_ILLINST, REGOFF_TRAPNO(%rsp)
1109 movq REGOFF_CS(%rsp), %rdi
1110 movq %rdi, REGOFF_ERR(%rsp)
1111 movq %rsp, %rdi
1112 movq REGOFF_RIP(%rsp), %rsi
1113 movl %gs:CPU_ID, %edx
1114 call trap
1115 jmp _sys_rtt
1116 7:
1117
1118 MSTATE_TRANSITION(LMS_USER, LMS_SYSTEM)
1119 movl REGOFF_RAX(%rsp), %eax /* (%rax damaged by mstate calls) */
1120
1121 ASSERT_LWPTOREGS(%r14, %rsp)
1122
1123 incq %gs:CPU_STATS_SYS_SYSCALL
1124
1125 /*
1126 * Make some space for MAXSYSARGS (currently 8) 32-bit args
1127 * placed into 64-bit (long) arg slots, plus one 64-bit
1128 * (long) arg count, maintaining 16 byte alignment.
1129 */
1130 subq $SYS_DROP, %rsp
1131 movb $LWP_SYS, LWP_STATE(%r14)
1132 movq %r15, %rdi
1133 movq %rsp, %rsi
1134 call syscall_entry
1135
1136 /*
1137 * Fetch the arguments copied onto the kernel stack and put
1138 * them in the right registers to invoke a C-style syscall handler.
1139 * %rax contains the handler address. For the last two arguments, we
1140 * push them onto the stack -- we can't clobber the old arguments.
1141 */
1142 movq %rax, %rbx
1143 movl 0x0(%rsp), %edi /* arg0 */
1144 movl 0x8(%rsp), %esi /* arg1 */
1145 movl 0x10(%rsp), %edx /* arg2 */
1146 movl 0x38(%rsp), %eax /* arg7 load */
1147 movl 0x18(%rsp), %ecx /* arg3 */
1148 pushq %rax /* arg7 saved to stack */
1149 movl 0x28(%rsp), %r8d /* arg4 */
1150 movl 0x38(%rsp), %eax /* arg6 load */
1151 movl 0x30(%rsp), %r9d /* arg5 */
1152 pushq %rax /* arg6 saved to stack */
1153
1154 call *SY_CALLC(%rbx)
1155
1156 movq %rbp, %rsp /* pop the args */
1157
1158 /*
1159 * amd64 syscall handlers -always- return a 64-bit value in %rax.
1160 * On the 32-bit kernel, the always return that value in %eax:%edx
1161 * as required by the 32-bit ABI.
1162 *
1163 * Simulate the same behaviour by unconditionally splitting the
1164 * return value in the same way.
1165 */
1166 movq %rax, %r13
1167 shrq $32, %r13 /* upper 32-bits into %edx */
1168 movl %eax, %r12d /* lower 32-bits into %eax */
1169
1170 /*
1171 * Optimistically assume that there's no post-syscall
1172 * work to do. (This is to avoid having to call syscall_mstate()
1173 * with interrupts disabled)
1174 */
1175 MSTATE_TRANSITION(LMS_SYSTEM, LMS_USER)
1176
1177 /*
1178 * We must protect ourselves from being descheduled here;
1179 * If we were, and we ended up on another cpu, or another
1180 * lwp got int ahead of us, it could change the segment
1181 * registers without us noticing before we return to userland.
1182 */
1183 cli
1184 CHECK_POSTSYS_NE(%r15, %r14, %ebx)
1185 jne _full_syscall_postsys32
1186 SIMPLE_SYSCALL_POSTSYS(%r15, %r14, %bx)
1187
1188 /*
1189 * To get back to userland, load up the 32-bit registers and
1190 * sysexit back where we came from.
1191 */
1192
1193 /*
1194 * Interrupts will be turned on by the 'sti' executed just before
1195 * sysexit. The following ensures that restoring the user's rflags
1196 * doesn't enable interrupts too soon.
1197 */
1198 andq $_BITNOT(PS_IE), REGOFF_RFL(%rsp)
1199
1200 /*
1201 * (There's no point in loading up %edx because the sysexit
1202 * mechanism smashes it.)
1203 */
1204 movl %r12d, %eax
1205 movl REGOFF_RBX(%rsp), %ebx
1206 movl REGOFF_RBP(%rsp), %ebp
1207 movl REGOFF_RSI(%rsp), %esi
1208 movl REGOFF_RDI(%rsp), %edi
1209
1210 movl REGOFF_RIP(%rsp), %edx /* sysexit: %edx -> %eip */
1211 pushq REGOFF_RFL(%rsp)
1212 popfq
1213 movl REGOFF_RSP(%rsp), %ecx /* sysexit: %ecx -> %esp */
1214 ALTENTRY(sys_sysenter_swapgs_sysexit)
1215 swapgs
1216 sti
1217 sysexit
1218 SET_SIZE(sys_sysenter_swapgs_sysexit)
1219 SET_SIZE(sys_sysenter)
1220 SET_SIZE(_sys_sysenter_post_swapgs)
1221 SET_SIZE(brand_sys_sysenter)
1222
1223 #endif /* __lint */
1224
1225 #if defined(__lint)
1226 /*
1227 * System call via an int80. This entry point is only used by the Linux
1228 * application environment. Unlike the other entry points, there is no
1229 * default action to take if no callback is registered for this process.
1230 */
1231 void
1232 sys_int80()
1233 {}
1234
1235 #else /* __lint */
1236
1237 ENTRY_NP(brand_sys_int80)
1238 SWAPGS /* kernel gsbase */
1239 XPV_TRAP_POP
1240
1241 /*
1242 * We first attempt to call the "b_int80" handler from the "struct
1243 * brand_mach_ops" for this brand. If no handler function is installed
1244 * for this brand, the BRAND_CALLBACK() macro returns here and we
1245 * check the lwp for a "lwp_brand_syscall" handler.
1246 */
1247 BRAND_CALLBACK(BRAND_CB_INT80, BRAND_URET_FROM_INTR_STACK())
1248
1249 /*
1250 * Check to see if this lwp provides "lwp_brand_syscall". If so, we
1251 * will route this int80 through the regular system call handling path.
1252 */
1253 movq %r15, %gs:CPU_RTMP_R15
1254 movq %gs:CPU_THREAD, %r15
1255 movq T_LWP(%r15), %r15
1256 movq LWP_BRAND_SYSCALL(%r15), %r15
1257 testq %r15, %r15
1258 movq %gs:CPU_RTMP_R15, %r15
1259 jnz nopop_syscall_int
1260
1261 /*
1262 * The brand provided neither a "b_int80", nor a "lwp_brand_syscall"
1263 * function, and has thus opted out of handling this trap.
1264 */
1265 SWAPGS /* user gsbase */
1266 jmp nopop_int80
1267
1268 ENTRY_NP(sys_int80)
1269 /*
1270 * We hit an int80, but this process isn't of a brand with an int80
1271 * handler. Bad process! Make it look as if the INT failed.
1272 * Modify %rip to point before the INT, push the expected error
1273 * code and fake a GP fault. Note on 64-bit hypervisor we need
1274 * to undo the XPV_TRAP_POP and push rcx and r11 back on the stack
1275 * because gptrap will pop them again with its own XPV_TRAP_POP.
1276 */
1277 XPV_TRAP_POP
1278 nopop_int80:
1279 subq $2, (%rsp) /* int insn 2-bytes */
1280 pushq $_CONST(_MUL(T_INT80, GATE_DESC_SIZE) + 2)
1281 #if defined(__xpv)
1282 push %r11
1283 push %rcx
1284 #endif
1285 jmp gptrap / GP fault
1286 SET_SIZE(sys_int80)
1287 SET_SIZE(brand_sys_int80)
1288 #endif /* __lint */
1289
1290
1291 /*
1292 * This is the destination of the "int $T_SYSCALLINT" interrupt gate, used by
1293 * the generic i386 libc to do system calls. We do a small amount of setup
1294 * before jumping into the existing sys_syscall32 path.
1295 */
1296 #if defined(__lint)
1297
1298 /*ARGSUSED*/
1299 void
1300 sys_syscall_int()
1301 {}
1302
1303 #else /* __lint */
1304
1305 ENTRY_NP(brand_sys_syscall_int)
1306 SWAPGS /* kernel gsbase */
1307 XPV_TRAP_POP
1308 call smap_enable
1309 BRAND_CALLBACK(BRAND_CB_INT91, BRAND_URET_FROM_INTR_STACK())
1310 jmp nopop_syscall_int
1311
1312 ALTENTRY(sys_syscall_int)
1313 SWAPGS /* kernel gsbase */
1314 XPV_TRAP_POP
1315 call smap_enable
1316
1317 nopop_syscall_int:
1318 movq %gs:CPU_THREAD, %r15
1319 movq T_STACK(%r15), %rsp
1320 movl %eax, %eax
1321 /*
1322 * Set t_post_sys on this thread to force ourselves out via the slow
1323 * path. It might be possible at some later date to optimize this out
1324 * and use a faster return mechanism.
1325 */
1326 movb $1, T_POST_SYS(%r15)
1327 CLEAN_CS
1328 jmp _syscall32_save
1329 /*
1330 * There should be no instructions between this label and SWAPGS/IRET
1331 * or we could end up breaking branded zone support. See the usage of
1332 * this label in lx_brand_int80_callback and sn1_brand_int91_callback
1333 * for examples.
1334 */
1335 ALTENTRY(sys_sysint_swapgs_iret)
1336 SWAPGS /* user gsbase */
1337 IRET
1338 /*NOTREACHED*/
1339 SET_SIZE(sys_sysint_swapgs_iret)
1340 SET_SIZE(sys_syscall_int)
1341 SET_SIZE(brand_sys_syscall_int)
1342
1343 #endif /* __lint */
1344
1345 /*
1346 * Legacy 32-bit applications and old libc implementations do lcalls;
1347 * we should never get here because the LDT entry containing the syscall
1348 * segment descriptor has the "segment present" bit cleared, which means
1349 * we end up processing those system calls in trap() via a not-present trap.
1350 *
1351 * We do it this way because a call gate unhelpfully does -nothing- to the
1352 * interrupt flag bit, so an interrupt can run us just after the lcall
1353 * completes, but just before the swapgs takes effect. Thus the INTR_PUSH and
1354 * INTR_POP paths would have to be slightly more complex to dance around
1355 * this problem, and end up depending explicitly on the first
1356 * instruction of this handler being either swapgs or cli.
1357 */
1358
1359 #if defined(__lint)
1360
1361 /*ARGSUSED*/
1362 void
1363 sys_lcall32()
1364 {}
1365
1366 #else /* __lint */
1367
1368 ENTRY_NP(sys_lcall32)
1369 SWAPGS /* kernel gsbase */
1370 pushq $0
1371 pushq %rbp
1372 movq %rsp, %rbp
1373 leaq __lcall_panic_str(%rip), %rdi
1374 xorl %eax, %eax
1375 call panic
1376 SET_SIZE(sys_lcall32)
1377
1378 __lcall_panic_str:
1379 .string "sys_lcall32: shouldn't be here!"
1380
1381 /*
1382 * Declare a uintptr_t which covers the entire pc range of syscall
1383 * handlers for the stack walkers that need this.
1384 */
1385 .align CPTRSIZE
1386 .globl _allsyscalls_size
1387 .type _allsyscalls_size, @object
1388 _allsyscalls_size:
1389 .NWORD . - _allsyscalls
1390 SET_SIZE(_allsyscalls_size)
1391
1392 #endif /* __lint */
1393
1394 /*
1395 * These are the thread context handlers for lwps using sysenter/sysexit.
1396 */
1397
1398 #if defined(__lint)
1399
1400 /*ARGSUSED*/
1401 void
1402 sep_save(void *ksp)
1403 {}
1404
1405 /*ARGSUSED*/
1406 void
1407 sep_restore(void *ksp)
1408 {}
1409
1410 #else /* __lint */
1411
1412 /*
1413 * setting this value to zero as we switch away causes the
1414 * stack-pointer-on-sysenter to be NULL, ensuring that we
1415 * don't silently corrupt another (preempted) thread stack
1416 * when running an lwp that (somehow) didn't get sep_restore'd
1417 */
1418 ENTRY_NP(sep_save)
1419 xorl %edx, %edx
1420 xorl %eax, %eax
1421 movl $MSR_INTC_SEP_ESP, %ecx
1422 wrmsr
1423 ret
1424 SET_SIZE(sep_save)
1425
1426 /*
1427 * Update the kernel stack pointer as we resume onto this cpu.
1428 */
1429 ENTRY_NP(sep_restore)
1430 movq %rdi, %rdx
1431 shrq $32, %rdx
1432 movl %edi, %eax
1433 movl $MSR_INTC_SEP_ESP, %ecx
1434 wrmsr
1435 ret
1436 SET_SIZE(sep_restore)
1437
1438 #endif /* __lint */